Stąd można pobrać programy na kalkulator TI83 - ti92.zip - 7 kB.

W pliku ti92.zip (po rozpakowaniu) znajdziesz dwie wersje programów:

1. Wersja gotowych programów *.92p do wczytania na kalkulator przy pomocy komputera i programu TI-Graph Link 92

2. Wersja plików tekstowych *.txt (patrz niżej) do ręcznego przepisania na kalkulatorze.

----- algorytm Euklidesa -----
algorytm(a,b)
Prgm
ClrIO
Disp  "NWD - ALGORYTM EUKLIDESA"
1->r
While  r>0
  mod(a,b)->r
  Disp  string(a)&"="&string(intDiv(a,b))&"*"&string(b)&"+"&string(r)
  b->a
  r->b
EndWhile
Disp  "NWD="&string(a)
EndPrgm
---- zamiana liczby na postać binanrą------
bin()
Prgm
ClrIO
Prompt  a
" "->s
While  a>0
  If mod(a,2)=0 Then
     "0"&s->s
  Else
     "1"&s->s
  EndIf
  int(a/2)->a
EndWhile
Disp  s
EndPrgm
--- gra w bramki (Idź na całość)------
bramki()
Prgm
ClrIO
For  n,1,3,1
    0->t[n]
EndFor
rand(3)->samochod
99->t[samochod]
(C)Disp string(t[1])&"  "&string(t[2])&"  "&string(t[3])
Input  "Ktora bramke wybierasz ",wybrana
1->t[wybrana]
1->n
While  t[n]>0
  rand(3)->n
EndWhile
n->pusta
1->t[pusta]
Disp  "Bramka nr "&string(pusta)&" jest pusta"
Input  "Czy zmieniasz decyzje t/n",taknie
If taknie=1 Then
   For  n,1,3,1
       If t[n]!=1 Then
          n->wybrana
       EndIf
   EndFor
EndIf
If samochod=wybrana Then
   Disp  "Wygrales!!!"
   Else
   Disp  "Przegrales :(((((((("
EndIf
EndPrgm
--- ciąg harmoniczny -------
ciagharm()
Prgm
For i,1,5,1
    Disp 1/i
EndFor
EndPrgm
---- dzielenie ------
dziel(licz,mian)
Prgm
ClrIO
Disp string(licz)&"/"&string(mian)&"="
"="&string(intDiv(licz,mian))&"."->s
For n,1,40,1
    mod(licz,mian)*10->licz
    s&string(intDiv(licz,mian))->s
EndFor
Disp s
EndPrgm
----- dzielenie do 175 miejsc po przecinku ------
dziel1(licz,mian)
Prgm
ClrIO
Disp  string(licz)&"/"&string(mian)&"="
"="&string(intDiv(licz,mian))&"."->s
For  n,1,175,1
    mod(licz,mian)*10->licz
    s&string(intDiv(licz,mian))->s
    If mod(n,25)=0 Then
       Disp  s
       "     "->s
    EndIf
EndFor
Disp  s
EndPrgm
---- rzut kostką --------
kostka()
Prgm
ZoomSqr
ClrDraw
For  n,1,6,1
    0->t[n]
EndFor
For  n,1,50,0.1
    rand(6)->los
    t[los]+0.1->t[los]
    Line  los*3-10,t[los]-5,los*3-8.5,t[los]-5
    Line  los*3-8.3,t[los]-5,los*3-7.8,t[los]-4.5
EndFor
EndPrgm
---- liczba pierwsza --------
pierwsza()
Prgm
ClrIO
Disp  "LICZBA PIERWSZA czy ZLOZONA"
Input  "Podaj liczbe ",a
For  dz,2,int(root(a)),1
    If  mod(a,dz)=0
    Exit
EndFor
If mod(a,dz)=0 Then
   Disp  "liczba zlozona"
Else
   Disp  "liczba pierwsza"
EndIf
EndPrgm
---- sito Eratostenesa -------
sito()
Prgm
ClrIO
Disp  "Sito Eratostenesa"
100->maks
For  n,1,maks,1
    n->t[n]
EndFor
For  n,2,int(root(maks)),1
    For  i,2,int(maks/n),1
        0->t[n*i]
    EndFor
EndFor
""->s
For  n,2,maks,1
    If  t[n]>0
       s&" "&string(t[n])->s
    If dim(s)>24 Then
       Disp  s
       ""->s
    EndIf
EndFor
Disp  s
EndPrgm
---- skracanie ułamków -------
skroc(l,m)
Prgm
ClrIO
string(l)&"/"&string(m)&"="->s
gcd(l,m)->n
l/n->l
m/n->m
Disp s&string(l)&"/"&string(m)
EndPrgm
--- wykresy funkcji --------
wykfun()
Prgm
ZoomSqr
For x,xmin,xmax,.1
    Circle x,sin(x),.1
EndFor
EndPrgm
---- wykresy nierówności ------
wyknier()
Prgm
ZoomSqr
For x,(-)5,5,.2
    For y,(-)5,5,.2
        If sin(x^2+y^2)>0 Then
           Circle x,y,.05
        EndIf
    DelVar EndFor
EndFor
EndPrgm
----- zaba (figury Sierpińskiego)------
zaba()
Prgm
ZoomDec
2/3->s
0->x
0->y
For i,1,100000,1
    rand(6)->l
    x+(4*cos(l*2*pi/6)-x)*s->x
    y+(4*sin(l*2*pi/6)-y)*s->y
    Circle x,y,.1
EndFor
EndPrgm
---- zamiana ułamka zwykłego na okresowy ------
zuzno(licz,mian)
Prgm
ClrIO
string(licz)&"/"&string(mian)&"="->s
Disp  s
gcd(licz,mian)->nwd1
licz/nwd1->licz
mian/nwd1->mian
"="&string(licz)&"/"&string(mian)&"="->s
s&string(factor(licz))&"/("&string(factor(mian))&")="->s
Disp  s
"="&string(intDiv(licz,mian))&"."->s
mian->mian1
0->i2
While  mod(mian1,2)=0
      i2+1->i2
      mian1/2->mian1
EndWhile
0->i5
While  mod(mian1,5)=0
      i5+1->i5
      mian1/5->mian1
EndWhile
max(i2,i5)->immpao
If  immpao=0
   s&"("->s
1->dlok
9->licz1
While  mod(licz1,mian1)>0
      dlok+1->dlok
      mod(licz1,mian1)*10+9->licz1
EndWhile
For  n,1,150,1
    mod(licz,mian)*10->licz
    s&string(intDiv(licz,mian))->s
    If  immpao=n
       s&"("->s
    If  immpao+dlok=n
       s&")"->s
    If mod(n,25)=0 Then
       Disp  s
       "   "->s
    EndIf
EndFor
Disp  s
EndPrgm
------------